MATRICES Son estructuras de datos estáticas encargadas de

MATRICES
Son estructuras de datos estáticas encargadas de almacenamiento de datos, se conocen
como array bidimensionales ya que define dos índices para el almacenamiento de
información, al igual que los vectores almacenan datos homogéneos, es decir de igual tipo
de datos ya sea primitivo o por referencia.
Los datos que se almacena en las matrices serán del mismo tipo, es decir si declaro la
matriz como integer los valores que ingresare serán de tipo integer. Las matrices a
diferencia de los vectores que utilizan un solo índice estas utilizan dos índices para
referencia una posición dentro de la estructura, es decir una matriz posee un índice para
referencia la fila y otro índice para referencia la columna. El siguiente gráfico representa
una matriz.
Declaración de una matriz: Para declarar una matriz debemos indicar el nombre de la
misma así como la cantidad de elementos que esta almacena en cada índice. La Sintaxis
en object pascal es la siguiente:
nombrematriz = array[puntoinicialfila..puntofinalfila, puntoinicialcolumna..puntofinalcolumna ] of tipodato
Ejemplo:
matriz:array[1..filas, 1..columnas] of Integer;
Como apreciamos los valores del punto inicial pueden estar definidos como:
•
Indexación base-cero (0): En este modo el primer elemento del array será la componente
cero (0) del mismo, es decir, tendrá el índice 0. En consecuencia, si el array tiene 'n'
componentes la última tendrá como índice el valor n-1.
•
Indexación base-uno (1): En esta forma de indexación, el primer elemento del
array tiene el índice 1 y el último tiene el índice n.
•
Indexación base-n (n): Este es un modo versátil de indexación en la que el índice
del primer elemento puede ser elegido libremente, en algunos lenguajes de
programación se permite que los índices puedan ser negativos
Ejemplo: declaración de una matriz de 3 filas y 4 columnas
Indexación Cero
matriz_datos = array[0..2, 0..3] of integer
Indexación Uno
matriz_datos = array[1..3, 1..4] of integer
Ahora para saber la cantidad de elementos que podemos almacenar en una matriz se
debe multiplicar el número de valores comprendido por el rango de filas y columnas. Es
decir para este ejemplo obtenemos 12 posiciones dentro de la matriz para
almacenamiento información de tipo integer.
Para la indexación cero el rango de fila esta dado desde 0 hasta 2 existiendo 3 valores
(0,1,2), para el rango de columnas esta dado desde 0 hasta 3 existiendo 4 valores
(0,1,2,3).
Para la indexación uno el rango de fila esta dado desde 1 hasta 3 existiendo 3 valores
(1,2,3), para el rango de columnas esta dado desde 1 hasta 4 existiendo 4 valores
(1,2,3,4).
A continuación diseñaremos en object pascal, las clases necesarios para solucionar un
problema que nos permita almacenar datos de tipo entero dentro de una matriz y realizar
la siguientes operaciones básicas sobre los elementos de la matriz: suma, promedio,
elemento mayor y promedio de la diagonal principal.
Unidad UDeclaraMatriz, en donde se implementa el código de la clase TMatriz:
unit UDeclaraMatriz;
{$mode objfpc}{$H+}
interface
uses
Classes, SysUtils;
const
filas = 3;
columnas = 3;
type
{ TMatriz }
TMatriz = class
private
matriz:array[1..filas, 1..columnas] of Integer;
public
Constructor create;
procedure setMatriz(f:integer; c:integer; dato:integer);
function getMatriz(f:integer; c:integer): integer;
function sumaMatriz:Integer;
function promedioMatriz:real;
function promedioPrincipal: real;
function mayorMatriz:integer;
end;
implementation
{ TMatriz }
constructor TMatriz.create;
var
i,j:integer;
begin
for i:=1 to filas do
begin
for j:=1 to columnas do
begin
setMatriz(i,j,0);
end;
end;
end;
procedure TMatriz.setMatriz(f: integer; c: integer; dato: integer);
begin
matriz[f][c]:=dato;
end;
function TMatriz.getMatriz(f: integer; c: integer): integer;
begin
Result:=matriz[f][c];
end;
function TMatriz.sumaMatriz: Integer;
var
i,j,suma:integer;
begin
suma:=0;
for i:=1 to filas do
begin
for j:=1 to columnas do
begin
suma:= suma + getMatriz(i,j);
end;
end;
Result:=suma;
end;
function TMatriz.promedioMatriz: real;
var
i,j,suma:integer;
prom:real;
begin
suma:=0;
for i:=1 to filas do
begin
for j:=1 to columnas do
begin
suma:= suma + getMatriz(i,j);
end;
end;
prom:=suma/(filas*columnas);
Result:=prom;
end;
function TMatriz.promedioPrincipal: real;
var
i,j,suma, cont:integer;
prom:real;
begin
cont:=0;
suma:=0;
for i:=1 to filas do
begin
for j:=1 to columnas do
begin
if i=j then
begin
suma:= suma + getMatriz(i,j);
cont:= cont + 1;
end;
end;
end;
prom:=suma/cont;
Result:=prom;
end;
function TMatriz.mayorMatriz: integer;
var
i,j, mayor: integer;
begin
mayor:=getMatriz(1,1);
for i:=1 to filas do
begin
for j:=1 to columnas do
begin
if getMatriz(i,j) > mayor then
begin
mayor:=getMatriz(i,j);
end;
end;
end;
Result:=mayor;
end;
end.
Unidad UVentanaMatriz, en donde se implementa el código de la clase TForm1:
unit UVentanaMatriz;
{$mode objfpc}{$H+}
interface
uses
Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs,UDeclaraMatriz, StdCtrls,
ComCtrls, Grids;
type
{ TForm1 }
TForm1 = class(TForm)
bGuardar: TButton;
bMostrar: TButton;
bLimpiar: TButton;
bInforme: TButton;
c: TEdit;
f: TEdit;
Label2: TLabel;
Label3: TLabel;
Label4: TLabel;
Label5: TLabel;
lisinforme: TListBox;
num: TEdit;
Label1: TLabel;
datosmat: TStringGrid;
upc: TUpDown;
upf: TUpDown;
procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
procedure FormCreate(Sender: TObject);
procedure FormShow(Sender: TObject);
procedure bGuardarClick(Sender: TObject);
procedure bInformeClick(Sender: TObject);
procedure bLimpiarClick(Sender: TObject);
procedure bMostrarClick(Sender: TObject);
private
mat:TMatriz;
public
end;
var
Form1: TForm1;
implementation
{ TForm1 }
procedure TForm1.FormShow(Sender: TObject);
begin
num.SetFocus;
end;
procedure TForm1.bGuardarClick(Sender: TObject);
var
dato:integer;
begin
dato:=StrToInt(num.Text);
mat.setMatriz(upf.Position, upc.Position, dato);
datosmat.Cells[upc.Position-1,upf.Position-1]:=num.Text;
if upc.Position < columnas then
begin
upc.Position:=upc.Position+1;
end
else
begin
if upf.Position < filas then
begin
upf.Position:=upf.Position+1;
upc.Position:=1;
end;
end;
num.Clear;
num.SetFocus;
end;
procedure TForm1.bInformeClick(Sender: TObject);
begin
lisinforme.Clear;
lisinforme.Items.Add('Suma de la matriz: '+IntToStr(mat.sumaMatriz));
lisinforme.Items.Add('Promedio de la matriz: '+FloatToStr(mat.promedioMatriz));
lisinforme.Items.Add('Mayor elemento: '+IntToStr(mat.mayorMatriz));
if filas = columnas then
begin
lisinforme.Items.Add('Promedio diagonal: '+FloatToStr(mat.promedioPrincipal));
end
else
lisinforme.Items.Add('La matriz no es cuadrada');
end;
procedure TForm1.bLimpiarClick(Sender: TObject);
var
i,j:integer;
begin
for i:=1 to filas do
begin
for j:=1 to columnas do
begin
mat.setMatriz(i,j,0);
datosmat.Cells[j-1,i-1]:='';
end;
end;
upf.Position:=1;
upc.Position:=1;
num.Clear;
lisinforme.Clear;
num.SetFocus;
end;
procedure TForm1.bMostrarClick(Sender: TObject);
var
i,j:Integer;
begin
for i:=1 to filas do
begin
for j:=1 to columnas do
begin
datosmat.Cells[j-1,i-1]:=IntToStr(mat.getMatriz(i,j));
end;
end;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
mat:=TMatriz.create;
upf.Max:=filas;
upc.Max:=columnas;
datosmat.ColCount:=columnas;
datosmat.RowCount:=filas;
end;
procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
mat.Free;
end;
initialization
{$I uventanamatriz.lrs}
end.